描画の過程を表示させない

'Windowsが起動してからの経過時間 API
Private Declare Function GetTickCount Lib "kernel32" () As Long

'mSecタイマー
Private Sub ExTimer(tim As Long)
    Dim st As Long
    
    '開始時間を取得
    st = GetTickCount
    DoEvents
    Do
        If GetTickCount - st >= tim Then
            '時間が経過した
            Exit Do
        End If
        DoEvents
    Loop
End Sub

'テスト用にオートシェイプを作成し回転させる
Private Sub ExShapeMake()
    Dim tshape As Shape
    Dim i As Double
    
    '元の図形を作成
    With ActiveSheet.Range("B7:E14")
        Set tshape = ActiveSheet.Shapes.AddShape(Type:=msoShapeLeftArrow, _
        Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
            
        '180度まで徐々に回転
        For i = 1 To 180
            '100mSecタイマー
            ExTimer 10
            '1度回転
            Call tshape.IncrementRotation(1)
        Next
    
    End With
    Set tshape = Nothing
End Sub

'描画の過程を表示
Private Sub CommandButton1_Click()
    Application.ScreenUpdating = True
    ExShapeMake
End Sub

'描画の過程を非表示
Private Sub CommandButton2_Click()
    Application.ScreenUpdating = False
    ExShapeMake
    Application.ScreenUpdating = True
End Sub