Excel VBA：オートシェイプを作成しタイマーで徐々に回転

Option Explicit

'Windowsが起動してからの経過時間 API
Private Declare Function GetTickCount Lib "kernel32" () As Long

'mSecタイマー
Private Sub ExTimer(tim As Long)
    Dim st As Long
    
    '開始時間を取得
    st = GetTickCount
    DoEvents
    Do
        If GetTickCount - st >= tim Then
            '時間が経過した
            Exit Do
        End If
        DoEvents
    Loop
End Sub

'シェイプを作成し回転する
Sub ExMakeShape()
    Dim tshape As Shape
    Dim i As Double
    
    '元の図形を作成
    With ActiveSheet.Range("D9:E15")
        Set tshape = ActiveSheet.Shapes.AddShape(Type:=msoShapeLeftArrow, _
        Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
    End With
    Set tshape = Nothing

    '回転させる図形を作成
    With ActiveSheet.Range("D9:E15")
        Set tshape = ActiveSheet.Shapes.AddShape(Type:=msoShapeLeftArrow, _
        Left:=.Left, Top:=.Top, Width:=.Width, Height:=.Height)
        '90度まで徐々に回転
        For i = 1 To 90
            '100mSecタイマー
            ExTimer 100
            '1度回転
            Call tshape.IncrementRotation(1)
        Next
    End With
    Set tshape = Nothing

End Sub

Private Sub CommandButton1_Click()
    ExMakeShape
End Sub