Excelで取引先表を作ってみよう

Step 17 「印刷」ボタンの設置

メニューに戻る

スポンサーリンク





メインフォームコード

'下のコードを追加してください

'印刷ボタン
Private Sub CommandButton9_Click()
    ExPrintPreview
End Sub


'印刷
Private Sub ExPrintPreview()
    Dim lrow As Long
    Dim i As Long
    
    '印刷シートをクリア
    lrow = Sheets("印刷").Range("A65536").End(xlUp).Row
    Sheets("印刷").Range("A1:L" & lrow).Delete

    lrow = Sheets("T取引先").Range("A65536").End(xlUp).Row
    If lrow = 4 Then
        MsgBox "印刷するデータが登録されていません。", , "取引先表"
        Exit Sub
    End If
    
    '別シートへコピー
    Worksheets("T取引先").Range("A4:H" & lrow).Copy Destination:=Worksheets("印刷").Range("A1")
    '空白行を削除し詰める
    For i = lrow To 2 Step -1
        If Sheets("印刷").Cells(i, 1) = "" Then
            'A列が空白なら行削除
            Sheets("印刷").Rows(i).Delete
        End If
    Next
        
    lrow = Sheets("印刷").Range("A65536").End(xlUp).Row
    '印刷範囲
    Sheets("印刷").PageSetup.PrintArea = "A1:H" & lrow
    '用紙サイズ
    Sheets("印刷").PageSetup.PaperSize = xlPaperA4
    '用紙方向
    Sheets("印刷").PageSetup.Orientation = xlLandscape

    '余白   センチをポイントに変換しセット
    Sheets("印刷").PageSetup.LeftMargin = Application.CentimetersToPoints(1)
    Sheets("印刷").PageSetup.RightMargin = Application.CentimetersToPoints(0.6)
    Sheets("印刷").PageSetup.TopMargin = Application.CentimetersToPoints(1.8)
    Sheets("印刷").PageSetup.BottomMargin = Application.CentimetersToPoints(1.1)
    Sheets("印刷").PageSetup.HeaderMargin = Application.CentimetersToPoints(1)
    Sheets("印刷").PageSetup.FooterMargin = Application.CentimetersToPoints(0.7)

    '印刷プレビュー
    Sheets("印刷").PrintPreview
End Sub

スポンサーリンク





実行結果

「印刷」ボタンの設置
印刷ボタンを設置したシート

印刷プレビュー画面
印刷プレビュー画面

スポンサーリンク






メニューに戻る

■■■
このサイトの内容を利用して発生した、いかなる問題にも一切責任は負いませんのでご了承下さい
■■■
当ホームページに掲載されているあらゆる内容の無許可転載・転用を禁止します


Copyright (c) Excel-Excel ! All rights reserved