ExcelでGoogleサイトマップ用xmlファイル作成ソフトを作ってみよう

Step 2 IEをオープンします

実行手順
1)「作成するサイトアドレス」のテキストボックスにURLが入力されているかチェックします。
2)CreateObject(InternetExplorer.application)でIEをオープンします。
3)正常にオープンされるまで30秒間ループで待ちます。
4)今回はIEを閉じ終了します。


Homeへ > Excelでアプリケーションソフト2 > xmlファイル作成ソフト

設定画面

「作成開始」ボタンをクリックすると開始します。
IEを開くシート


実行VBAコード

Option Explicit

Private tIEobj As Object

Private Function ExIeOpen() As Boolean
    Dim sttime As Long
    Dim passtime As Long
    
    ExIeOpen = False
On Error GoTo ErrExit
    Set tIEobj = CreateObject("InternetExplorer.application")
    tIEobj.navigate TextBox1
    
    '読み終わるまで待つ
    sttime = Timer
    Do
        '経過時間
        passtime = Timer - sttime
        DoEvents
        '30秒経過すると抜ける
        If passtime >= 30 Then
            Exit Do
        End If
        '読込み完了
        If tIEobj.ReadyState = 4 Then
            Exit Do
        End If
    Loop
    Application.Cursor = xlNormal
    'IEチェック
    If tIEobj.ReadyState <> 4 Then
        MsgBox "IEをオープンできませんでした。処理を中止します。"
    Else
        If LCase(tIEobj.document.URL) <> LCase(TextBox1) Then
            MsgBox "入力されたURLを開くことができませんでした。URLを確認してください。"
            TextBox1.Activate
        Else
            ExIeOpen = True
        End If
    End If
    Exit Function
ErrExit:
    Application.Cursor = xlNormal
    MsgBox "処理中にエラーが発生しました。処理を中止します。" & vbCrLf & Err.Description
On Error Resume Next
    tIEobj.Quit
    Set tIEobj = Nothing
End Function

'作成開始ボタンをクリック
Private Sub CommandButton1_Click()
    If TextBox1 = "" Then
        MsgBox "作成するサイトアドレスを入力してください。"
        TextBox1.Activate
        Exit Sub
    End If
    
    'マウスポインターを砂時計に
    Application.Cursor = xlWait
    'IEをオープン
    ExIeOpen
    'IEを閉じる
    tIEobj.Quit
    Set tIEobj = Nothing
    Application.Cursor = xlNormal
End Sub


Homeへ > Excelでアプリケーションソフト2 > xmlファイル作成ソフト

■■■
このサイトの内容を利用して発生した、いかなる問題にも一切責任は負いませんのでご了承下さい
■■■
当ホームページに掲載されているあらゆる内容の無許可転載・転用を禁止します


Copyright (c) Excel-Excel ! All rights reserved