Excel2007で顧客管理ソフトを作ってみよう

最大の顧客No..を探すには、MAXワークシート関数を使用しています。
ans = Application.WorksheetFunction.Max(tRange)
これでtRange内の最大値が取得できます。
次にFindメソッドで、セル位置を取得します。
Set tRange = tRange.Find(What:=ans, LookIn:=xlValues, LookAt:=xlWhole)
What:=ans：　検索する値
LookIn:=xlValues：　検索の対象を値としています。
LookAt:=xlWhole)：　完全に同じセルを検索します。
条件に当てはまるセル が存在しない場合には、Nothingが返るので、  If Not tRange Is Nothing Then　で判定しています。

'最終ボタン
Private Sub CommandButton4_Click()
    Dim sr As String
    
    If ExFindMaxRange(sr) Then
        If ExDataChangeMsg = False Then
            Exit Sub
        End If
    
        ExDataDisp sr
    Else
        Beep
    End If
End Sub


'指定範囲から最大値を検索
Private Function ExFindMaxRange(ByRef srow As String) As Boolean
    Dim ans As Long
    Dim tRange As Range
    
    ExFindMaxRange = False
    '1列目の最大値を捜す
    Set tRange = Sheets("一覧").Columns(1)
    ans = Application.WorksheetFunction.Max(tRange)
    
    '最大値のセルを取得
    Set tRange = tRange.Find(What:=ans, LookIn:=xlValues, LookAt:=xlWhole)
    If Not tRange Is Nothing Then
        srow = tRange.Address(RowAbsolute:=False, ColumnAbsolute:=False)
        ExFindMaxRange = True
    End If
End Function